'From Cuis 1.0 of 28 November 2009 [latest update: #337] on 8 December 2009 at 11:21:21 pm'!

!Parser methodsFor: 'public access' stamp: 'eem 6/19/2008 09:38'!
encoder
	encoder isNil ifTrue:
		[encoder := EncoderForV3PlusClosures new].
	^encoder! !


!SystemDictionary methodsFor: 'Compiler swapping' stamp: 'jmv 12/8/2009 23:18'!
usingClosureCompiler
	^false not! !

"Postscript:
Recompile the system and do some minimal clean-ups"
"Recompile the system except the one method we can't yet deal with in GeniePlugin (1 too many literals)"
| classes compilationErrors |
Preferences setPreference: #allowBlockArgumentAssignment toValue: true.
compilationErrors := Set new.
classes := Smalltalk forgetDoIts allClasses reject: [:c| c name == #GeniePlugin].
'Recompiling The System'
	displayProgressAt: Sensor cursorPoint
	from: 0 to: classes size
	during:
		[:bar |
		classes withIndexDo:
			[:c :i|
			bar value: i.
			{ c. c class } do:
				[:b|
				"Transcript cr; print: b; endEntry."
				b selectors "asSortedCollection" do:
					[:s|
					[b recompile: s from: b]
						on: Error
						do: [:ex|
							Transcript
								cr; nextPutAll: 'COMPILATION ERROR: ';
								print: b; nextPutAll: '>>'; nextPutAll: s; flush.
							compilationErrors add: (MethodReference class: b selector: s)]]]]].
compilationErrors notEmpty ifTrue: [
	Smalltalk
		browseMessageList: compilationErrors asSortedCollection
		name: 'Compilation Errors'].
"Preferences setPreference: #allowBlockArgumentAssignment toValue: false"!

