'From Cuis 1.0 of 2 July 2009 [latest update: #215] on 13 July 2009 at 12:03:10 pm'!

!BrowserCommentTextMorph methodsFor: 'updating' stamp: 'jmv 7/13/2009 12:02'!
noteNewOwner: win
	super noteNewOwner: win.
	browserWindow _ win.
	win ifNil: [ ^self ].
	"#browserClassCommentPane has no other sender.
	However, don't remove this.
	We need some kind of reference to me, otherwise I'll get collected, when I am
	removed from my owner (the window) when not shown, and no other reference
	to me exists."
	win setProperty: #browserClassCommentPane toValue: self! !

!BrowserCommentTextMorph methodsFor: 'accessing' stamp: 'jmv 7/13/2009 12:01'!
lowerPane: aMorph

	"Set the AlignmentMorph that I live beneath"
	browserLowerPane _ aMorph! !


!CodeHolder methodsFor: 'misc' stamp: 'jmv 7/13/2009 11:58'!
addLowerPanesTo: window at: nominalFractions with: editString

	| verticalOffset column innerFractions |
	column _ AlignmentMorph proportional.
	verticalOffset _ 0.
	innerFractions _ 0@0 corner: 1@0.
	verticalOffset _ self addOptionalAnnotationsTo: column at: innerFractions plus: verticalOffset.
	verticalOffset _ self addOptionalButtonsTo: column  at: innerFractions plus: verticalOffset.

	column 
		addMorph: ((self buildMorphicCodePaneWith: editString) borderWidth: 0)
		fullFrame: (
			LayoutFrame 
				fractions: (innerFractions withBottom: 1) 
				offsets: (0@verticalOffset corner: 0@0)
		).
	window 
		addMorph: column
		frame: nominalFractions.

	column on: #mouseEnter send: #paneTransition: to: window.
	column on: #mouseLeave send: #paneTransition: to: window.
	^column! !


!Browser methodsFor: 'construction' stamp: 'jmv 7/13/2009 12:01'!
addLowerPanesTo: window at: nominalFractions with: editString
	| commentPane column |
	column _ super addLowerPanesTo: window at: nominalFractions with: editString.
	commentPane _ self buildMorphicCommentPane.
	window addMorph: commentPane fullFrame: (LayoutFrame fractions: (0@0.75 corner: 1@1)).
	commentPane lowerPane: column.
	self changed: #editSelection.! !

